RSI切線突破選股指標（TDX）..

老海侃線 2009-11-21

展開全文

RSI切線突破選股指標（TDX）

本帖最后由 yinchoo 于 2009-7-25 09:10 編輯

1、對于RSI指標的運用請查壇中偉哥、井中月、cqcsshw 、九陽等高手的貼子：
http://www./viewthread.php?tid=36200&highlight=RSI

http://www./viewthread.php?tid=36267&highlight=RSI

http://www./viewthread.php?tid=36199&highlight=RSI

http://www./viewthread.php?tid=36215&highlight=RSI

2、指標用法：
本選股指標意在眾多的股票中，快速選出RSI突破切線的個股。但不意味著，選出后個股就會上漲。因為：這個切線理論到底有多大的成功率是未知；我的選股條件限制是不是合理待核實；

就象壇中一位朋友所說，切線是藝術。加上我的水平所限，發現很多情況下，選股指標畫的線根本就不是切線，因此我采用了畫4線的方法來克服。就是這樣，仍畫出很多失敗的切線。因此，需要您在選出股票后再看一下切線指標或手工畫一下；

這個指標在RSI值實現“第①高點”變化后，畫線會自動變化。因此，本指標只適用當天選股，不適用特定期間段選股。

請不要過于迷信任一指標，歷史并不一定代表未來。我的理解是：看指標就是賭概率。因此，建議您在選出股票后，結合其他多個指標看一下。

3、選股指標公式（用于選股）：
{M1 1    100 6}
{N2 1    100 20}

{RSI}
LC:=REF(CLOSE,1);
RSIV:=SMA(MAX(CLOSE-LC,0),M1,1)/SMA(ABS(CLOSE-LC),M1,1)*100;
RSI2:=SMA(MAX(CLOSE-LC,0),12,1)/SMA(ABS(CLOSE-LC),12,1)*100;
RSI3:=SMA(MAX(CLOSE-LC,0),24,1)/SMA(ABS(CLOSE-LC),24,1)*100;
RSIV1:=SMA(MAX(CLOSE-LC,0),M1,1)/SMA(ABS(CLOSE-LC),M1,1)*100;
H_C:=RSIV<REF(RSIV,1) AND REF(RSIV,1)>REF(RSIV,2);
H_N:=CONST(COUNT(H_C,N2));
T_A:=CONST(SUMBARS(COUNT(H_C,1),H_N))+1;
{確認5個高點}
TT1:=CONST(BARSLAST(H_C))+1;
TT2:=CONST(SUMBARS(COUNT(H_C,1),2));
TT3:=CONST(SUMBARS(COUNT(H_C,1),3));
TT4:=CONST(SUMBARS(COUNT(H_C,1),4));
TT5:=CONST(SUMBARS(COUNT(H_C,1),5));
TT6:=CONST(SUMBARS(COUNT(H_C,1),6));
VV1:=CONST(REF(RSIV,TT1));
VV2:=CONST(REF(RSIV,TT2));
VV3:=CONST(REF(RSIV,TT3));
VV4:=CONST(REF(RSIV,TT4));
VV5:=CONST(REF(RSIV,TT5));
VV6:=CONST(REF(RSIV,TT6));
{確認  第1點與第2點切線}
切線1:=DRAWLINE(BARSLAST(RSIV=VV2)=0,RSIV,BARSLAST(RSIV=VV1)=0,RSIV,3);
{確認  最高點及最近5高點中的高點  切線}
V0:=CONST(HHV(RSIV,N2));
T0:=BARSLAST(RSIV=V0)+1;
MAXV:=MAX(VV1,MAX(VV2,MAX(VV3,MAX(VV4,VV5))));
MAXT:=BARSLAST(RSIV=MAXV);
切線2:=DRAWLINE(BARSLAST(RSIV=V0)=0,RSIV,BARSLAST(RSIV=MAXV)=0,RSIV,3);
{確認  最高點及第1高點  切線}
切線3:=DRAWLINE(BARSLAST(RSIV=V0)=0,RSIV,BARSLAST(RSIV=VV1)=0,RSIV,3);
未穿越:=NOT(HHV(RSIV,T0-1)>REF(切線3,BARSLAST(RSIV=HHV(RSIV,T0-1))=0));
{確認  最高點及前3高點的高點  切線}
MAXV1:=MAX(VV1,MAX(VV2,VV3));
MAXT1:=BARSLAST(RSIV=MAXV);
切線4:=DRAWLINE(BARSLAST(RSIV=V0)=0,RSIV,BARSLAST(RSIV=MAXV1)=0,RSIV,3);
{確認短期內是否背離}
VV7:=MAX(VV1,MAX(VV2,VV3));
TT7:=BARSLAST(RSIV=VV7)+1;
VV8:=MAX(VV4,MAX(VV5,VV6));
TT8:=BARSLAST(RSIV=VV8)+1;
同向1:=VV7>=VV8 AND REF(C,TT7)>=REF(C,TT8);
同向2:=VV7<VV8 AND REF(C,TT7)<REF(C,TT8);
{同向1:=V0>=MAX(RSIV,VV1) AND REF(C,T0)>=MAX(C,REF(C,TT1));
同向2:=V0>=MAX(RSIV,VV1) AND REF(C,T0)<MAX(C,REF(C,TT1));}
同向:=同向1 OR 同向2;
{確認突破切線}
上穿1:=VV2>VV1 AND CROSS(RSIV,切線1);
上穿2:=T0>MAXT AND CROSS(RSIV,切線2);
上穿3:=T0>TT1 AND 未穿越 AND CROSS(RSIV,切線3);
上穿4:=T0>MAXT1 AND CROSS(RSIV,切線4);
上穿:=上穿1 OR 上穿2 OR 上穿3 OR 上穿4;
{確認啟動點位置}
啟動:=RSIV<80 AND RSIV>REF(RSIV,1) AND (CROSS(RSIV,50) OR REF(RSIV,1)<50);
SELECT:啟動 AND 同向 AND 上穿;

4、RSI切線指標公式（用于顯示畫線，也可綜合選股中設定select達到80實現選股）：
{M1 1    100 6}
{N2 1    100 20}
{RSI}
LC:=REF(CLOSE,1);
RSIV:SMA(MAX(CLOSE-LC,0),M1,1)/SMA(ABS(CLOSE-LC),M1,1)*100;
RSI2:SMA(MAX(CLOSE-LC,0),12,1)/SMA(ABS(CLOSE-LC),12,1)*100;
RSI3:SMA(MAX(CLOSE-LC,0),24,1)/SMA(ABS(CLOSE-LC),24,1)*100;
RSIV1:=SMA(MAX(CLOSE-LC,0),M1,1)/SMA(ABS(CLOSE-LC),M1,1)*100;
H_C:=RSIV<REF(RSIV,1) AND REF(RSIV,1)>REF(RSIV,2);
H_N:=CONST(COUNT(H_C,N2));
T_A:=CONST(SUMBARS(COUNT(H_C,1),H_N))+1;
{確認5個高點}
TT1:=CONST(BARSLAST(H_C))+1;
TT2:=CONST(SUMBARS(COUNT(H_C,1),2));
TT3:=CONST(SUMBARS(COUNT(H_C,1),3));
TT4:=CONST(SUMBARS(COUNT(H_C,1),4));
TT5:=CONST(SUMBARS(COUNT(H_C,1),5));
TT6:=CONST(SUMBARS(COUNT(H_C,1),6));
VV1:=CONST(REF(RSIV,TT1));
VV2:=CONST(REF(RSIV,TT2));
VV3:=CONST(REF(RSIV,TT3));
VV4:=CONST(REF(RSIV,TT4));
VV5:=CONST(REF(RSIV,TT5));
VV6:=CONST(REF(RSIV,TT6));
{確認  第1點與第2點切線}
切線1:DRAWLINE(BARSLAST(RSIV=VV2)=0,RSIV,BARSLAST(RSIV=VV1)=0,RSIV,3);
{確認  最高點及最近5高點中的高點  切線}
V0:=CONST(HHV(RSIV,N2));
T0:=BARSLAST(RSIV=V0)+1;
MAXV:=MAX(VV1,MAX(VV2,MAX(VV3,MAX(VV4,VV5))));
MAXT:=BARSLAST(RSIV=MAXV);
切線2:DRAWLINE(BARSLAST(RSIV=V0)=0,RSIV,BARSLAST(RSIV=MAXV)=0,RSIV,3);
{確認  最高點及第1高點  切線}
切線3:DRAWLINE(BARSLAST(RSIV=V0)=0,RSIV,BARSLAST(RSIV=VV1)=0,RSIV,3);
未穿越:=NOT(HHV(RSIV,T0-1)>REF(切線3,BARSLAST(RSIV=HHV(RSIV,T0-1))=0));
{確認  最高點及前3高點的高點  切線}
MAXV1:=MAX(VV1,MAX(VV2,VV3));
MAXT1:=BARSLAST(RSIV=MAXV);
切線4:DRAWLINE(BARSLAST(RSIV=V0)=0,RSIV,BARSLAST(RSIV=MAXV1)=0,RSIV,3);
{確認短期內是否背離}
VV7:=MAX(VV1,MAX(VV2,VV3));
TT7:=BARSLAST(RSIV=VV7)+1;
VV8:=MAX(VV4,MAX(VV5,VV6));
TT8:=BARSLAST(RSIV=VV8)+1;
同向1:=VV7>=VV8 AND REF(C,TT7)>=REF(C,TT8);
同向2:=VV7<VV8 AND REF(C,TT7)<REF(C,TT8);

同向:=同向1 OR 同向2;
{確認突破切線}
上穿1:=VV2>VV1 AND CROSS(RSIV,切線1);
上穿2:=T0>MAXT AND CROSS(RSIV,切線2);
上穿3:=T0>TT1 AND 未穿越 AND CROSS(RSIV,切線3);
上穿4:=T0>MAXT1 AND CROSS(RSIV,切線4);
上穿:=上穿1 OR 上穿2 OR 上穿3 OR 上穿4;
{確認啟動點位置}
啟動:=RSIV<80 AND RSIV>REF(RSIV,1) AND (CROSS(RSIV,50) OR REF(RSIV,1)<50);
SELECT:IF(啟動 AND 同向 AND 上穿,80,20);