指標

J線共振
用法注釋：
黃綠相間為長J、紅藍相間是短線、低位共振同色買、變異減倉出手快。
大智慧二代
DRAWTEXTREL(10,2,'黃綠相間為長J、紅藍相間是短線、低位共振同色買、變異減倉出手快。'),COLORMAGENTA;
RSV1:=(CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100;
K1:=SMA(RSV1,5,1);
D1:=SMA(K1,5,1);
J1:=3*K1-2*D1;
AA1:=EMA(J1,5);
AA2:=REF(AA1,1);
STICKLINE(AA1>AA2,AA1,AA2,8,0),COLOR0055AA;{長J}
STICKLINE(AA1>AA2,AA1,AA2,5,0),COLOR0077CC;
STICKLINE(AA1>AA2,AA1,AA2,3,0),COLOR0099DD;
STICKLINE(AA1>AA2,AA1,AA2,1,0),Color01BEE7;
STICKLINE(AA1<=AA2,AA1,AA2,8,0),COLOR006600;
STICKLINE(AA1<=AA2,AA1,AA2,5,0),COLOR009900;
STICKLINE(AA1<=AA2,AA1,AA2,3,0),COLOR00BB00;
STICKLINE(AA1<=AA2,AA1,AA2,1,0),COLOR00CC00;
RSV2:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K2:=SMA(RSV2,3,1);
D2:=SMA(K2,3,1);
J2:=3*K2-2*D2;
BB1:=EMA(J2,5);
BB2:=REF(BB1,1);
STICKLINE(BB1>BB2,BB1,BB2,7,0),COLOR000045;{短J}
STICKLINE(BB1>BB2,BB1,BB2,5,0),COLOR000085;
STICKLINE(BB1>BB2,BB1,BB2,3,0),COLOR0000C5;
STICKLINE(BB1>BB2,BB1,BB2,1,0),COLOR0000E5;
STICKLINE(BB1<=BB2,BB1,BB2,7,0),COLOR353500;
STICKLINE(BB1<=BB2,BB1,BB2,5,0),COLOR555500;
STICKLINE(BB1<=BB2,BB1,BB2,3,0),COLOR757500;
STICKLINE(BB1<=BB2,BB1,BB2,1,0),COLOR858500;
DD:=AA1>AA2 AND BB1>BB2;
注意買入:DD AND NOT(REF(DD,1)) AND (AA1<50 OR BB1<50) ,LINETHICK0;
DRAWICON(注意買入,-5,7),ALIGN0;
注意賣出:REF(DD,1)=1 AND NOT(DD),LINETHICK0;
DRAWICON(注意賣出,105,8),ALIGN0;

通達信KDJ與MACD同圖顯示
DIF:(EMA(CLOSE,12)-EMA(CLOSE,26))*100;
DEA:EMA(DIF,9);
MACD:(DIF-DEA)*2,COLORSTICK;
DRAWICON(CROSS(DIF,DEA),DEA,1);
DRAWICON(CROSS(DEA,DIF),DEA,2);

IF(DIF<DEA,DIF,DRAWNULL),COLORGREEN;
DD:=C=HHV(C,180);
EE:=DEA< REF(DEA,1) AND REF(DEA< REF(DEA,1),1)=1;
CC:=C> REF(C,1) AND REF(C> REF(C,1),1)=1;
頂背離:=(DD AND EE AND DEA< HHV(DEA,180))*DEA;
A2:=BARSLAST(REF(CROSS(DEA,DIF),1));
{頂背:=REF(CLOSE,A2+1)<CLOSE AND REF(DIF,A2+1)>DIF AND CROSS(DEA,DIF);}
DRAWLINE(A2=0,DEA,頂背離,DEA,0),COLORRED,LINETHICK2;
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:SMA(RSV,9,3),COLORYELLOW;
D:SMA(K,9,3),COLORWHITE;
J:3*K-2*D,COLORMAGENTA;
IF(J<D,J,DRAWNULL),COLORFFEE44;
A1:=BARSLAST(REF(CROSS(DIF,DEA),1));
B1:=REF(C,A1+1)>C AND REF(DIF,A1+1)<DIF AND CROSS(DIF,DEA);
A22:=BARSLAST(REF(CROSS("KDJ.K"(9,3,3),"KDJ.D"(9,3,3)),1));
B2:=REF(C,A22+1)>C AND REF("KDJ.K"(9,3,3),A22+1)<"KDJ.K"(9,3,3) AND CROSS("KDJ.K"(9,3,3),"KDJ.D"(9,3,3));
A3:=BARSLAST(REF(CROSS("RSI.RSI1"(6,12,24),"RSI.RSI2"(6,12,24)),1));
B3:=REF(C,A3+1)>C AND REF("RSI.RSI1"(6,12,24),A3+1)<"RSI.RSI1"(6,12,24) AND CROSS("RSI.RSI1"(6,12,24),"RSI.RSI2"(6,12,24));
DRAWTEXT(B1,DEA-0.20,'▲MACD底背'),COLORWHITE;
DRAWTEXT(B2,D-0.20,'●KDJ底背'),COLORFF00FF;
{DJ:=CROSS(J,D) AND D<20;
DRAWTEXT(DJ,J-0.3,'低金叉'),COLORCYAN;
MDJ:=CROSS(DIF,DEA) AND DEA<0;
DRAWTEXT(MDJ,DEA-0.3,'低金叉'),COLORGREEN;
DRAWTEXT(CROSS(DEA,DIF),DIF+0.3,'死叉'),COLORYELLOW;
DRAWTEXT(CROSS(D,J),J+0.3,'死叉'),COLORRED;}
A:=CROSS(DIF,DEA) AND CROSS(K,D) AND CROSS(J,D);
DRAWICON(A,LOW*0.98,1);
B4:CROSS(DIF,DEA) AND CROSS("KDJ.K"(9,3,3),"KDJ.D"(9,3,3));
DRAWTEXT(B4,L-0.20,'★金叉共振'),COLOR0099FF;

 

    漲停預警(通達信)
    均線82:=REF(C,1)/REF(C,2)<=0.93 AND BETWEEN(C/REF(C,1),1.03,0.97) AND CLOSE/REF(CLOSE,8)<=0.8 AND BETWEEN(REF(C,2)/REF(C,3),1.04,0.96) AND BETWEEN(REF(C,3)/REF(C,4),1.04,0.96),LINETHICK0,COLORYELLOW;
STICKLINE(均線82,0,4,8,0),COLORRED;
選股:均線82,COLORWHITE; 

 

通達信中精確的獲取跨周期數據。

另外，公式只能幫助小周期引用大周期的數據（即向上引用），如果要引用小時數據的話，需對程序中的
“DAYS1970:=N*365+N1+(Y-1)*30+YS2+R-X;   {從基準年1月1日開始計算到當前的總天數}”
部分進行修改，可以改成更小時間周期的，只要軟件數據支持。

又另，引用公式中的基準年份“1970”好奇怪，為什么不直接取個閏年做基準年份，搞的還要“N-2”那么麻煩，懷疑1970是不是作者的生日。廢話多了點！ 下面正式開始

1：周線（引用公式）
N:=YEAR-1970;         {設1970為基準年份，距基準年份有幾年}
N1:=INTPART((N-2)/4); {閏年數，注意：計算中不包含當前年份。另：N-2的意思是基準年后2年即1972年是最近的一個閏年}
F:=(N-2)-N1*4;        {當前年份是否閏年}
Y:=MONTH;             {月份。注意：以下月份的天數以30天為準進行修正}
XX:=IF(Y>=3 AND F>=1,2,IF(Y>=3 AND F=0,1,0));               {2月份缺少的天數}
YS2:=IF(Y=2 OR Y=3,1,
        IF(Y=4 OR Y=5,2,
        IF(Y=6 OR Y=7,3,
        IF(Y=8,4,
        IF(Y=9 OR Y=10,5,
        IF(Y=11 OR Y=12,6,
        0))))))-XX;     {有31天的大月的天數修正}
X:=IF(F=0,1,0);   {當前年份是否閏年的修正天數}
R:=DAY;           {當月的日期}
DAYS1970:=N*365+N1+(Y-1)*30+YS2+R-X;   {從基準年1月1日開始計算到當前的總天數}
Z:=((DAYS1970-REF(DAYS1970,1))>(WEEKDAY-REF(WEEKDAY,1))) OR BARSCOUNT(C)=1;  {看兩個相鄰周期是否跨周}
T:=BARSLAST(Z);
O1:IF(T,REF(O,T),O);
H1:HHV(H,T+1);
L1:LLV(L,T+1);
C1:C;

2：日線顯示周線數據
OO:"周線.O1#WEEK";
HH:"周線.H1#WEEK";
LL:"周線.L1#WEEK";
CC:"周線.C1#WEEK";

其實可以在通達信中直接將“周線（引用公式）”源碼的最后部分改為
O1:IF(T,REF(O,T),O),NODRAW;
H1:HHV(H,T+1),NODRAW;
L1:LLV(L,T+1),NODRAW;
C1:C,NODRAW;
DRAWKLINE(H1,O1,L1,C1);

然后設為副圖指標，在日線圖中調出來與日K線對照比較。每一根日K線都有一根相對應的周K線。大家在周K線中會看到一周內日K線對應的周K線開盤價都是一樣的，因為從周線的角度來看周K線只能有一個開盤價。周最高最低開盤價的變化與其在一周內出現的早晚對圖形產生影響。廢話不多說，貼個圖來直觀的看。
{月K線}
DAYS:=DATETODAY(DATE)-DAY;   {從1990.12.19開始計算到當前的總天數}
Z:=((DAYS-REF(DAYS,1))>(MONTH-REF(MONTH,1))) OR BARSCOUNT(C)=1;  {看兩個相鄰周期是否跨周}
T:=BARSLAST(Z);
O1:IF(T,REF(O,T),O),NODRAW;
H1:HHV(H,T+1),NODRAW;
L1:LLV(L,T+1),NODRAW;
C1:C,NODRAW;
DRAWKLINE(H1,O1,L1,C1);

{年K線}
N:=YEAR-1970;
N1:=INTPART((N-2)/4);
DAYS:=N*365+N1;
Z:=((DAYS-REF(DAYS,1))>(YEAR-REF(YEAR,1))) OR BARSCOUNT(C)=1;
T:=BARSLAST(Z);
O1:IF(T,REF(O,T),O),NODRAW;
H1:HHV(H,T+1),NODRAW;
L1:LLV(L,T+1),NODRAW;
C1:C,NODRAW;
DRAWKLINE(H1,O1,L1,C1);

看到這些指標圖，，我首先想到的是，，當前價格在一周、一月、一年內的相對位置！?。〈蠹液煤冒l揮想象力吧！！！

 

仿寫的首富軟件壓力支撐位指標，正版軟件上該指標原名為“YLZCW ”。
我已和正版首富軟件的指標對照過了，線型，顏色，包括指標數值的小數，完全和正版指標相同。仿寫指標可以在大智慧新一代或通達信上使用。
源碼如下：
{YLZCW   主圖 即首富壓力支撐位 參數N:1,500,13;   M:1,500,55}
RSV13:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
K13:=SMA(RSV13,3,1);
D13:=SMA(K13,3,1);
J13:=3*K13-2*D13;
RSV55:=(CLOSE-LLV(LOW,M))/(HHV(HIGH,M)-LLV(LOW,M))*100;
K55:=SMA(RSV55,3,1);
D55:=SMA(K55,3,1);
J55:=3*K55-2*D55;
YLW:IF(CROSS(J55,J13),HIGH,REF(HIGH,BARSLAST(CROSS(J55,J13)))),COLORRED;
ZCW:IF(CROSS(J13,J55),LOW,REF(LOW,BARSLAST(CROSS(J13,J55)))),COLORBLUE;

初學乍練寫公式，前幾天斗膽在理想論壇上公布了該源碼，得到各位老師的鼓勵, 特別是得到了屬于偶像級的大慶老楊老師的鼓勵，心里非常高興。許多老師都建議公布源碼時最好附上對照的圖，其實我也是這么想的。不瞞大家說，我在發貼時發過圖，可自以為會發圖不難的我, 卻始終發不出去，最后只好作罷。今天在理想論壇中看到一篇介紹理想論壇中可行的發圖方法的帖子，才知道自己錯在哪里。今天特地重發指標，并補上圖。就算是新手練習吧。

 

要判斷一個股票的底部，我們必須結合指標來判斷，最簡單的方法有以下幾個方面：
（1）KDJ指標的J值在0以下，即負數；
（2）CCI指標的數值在一200附近；
（3）股價在BOLL下軌或者以下；
（4）股價遠離5日平均線至少10％以上。
只有滿足了上面4個條件，一般情況下股價就面臨底部
寂寞先生底部選股陽線買選股公式
TYP:=(HIGH+LOW+CLOSE)/3;
CCI:=(TYP-MA(TYP,14))/(0.015*AVEDEV(TYP,14));
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(RSV,3,1);
D:=SMA(K,3,1);
J:=3*K-2*D;
BOLL:=MA(CLOSE,20);
UPPER:=BOLL+2*STD(CLOSE,20);
LOWER:=BOLL-2*STD(CLOSE,20);
MA1:=MA(CLOSE,5);
陽線買:CCI<-200  AND J<0 AND CLOSE<LOWER AND CLOSE<MA1/1.1;

 

這個指標是專用于抄底逃頂。
這樣使用比較好：紅柱后三線是否粘合考慮抄底，綠柱后就走人。

{估抄底F-通用}
RSV1:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
RSV2:=(CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100;
J1:=SMA(RSV1,3,1);J2:=SMA(J1,3,1);
趨勢線:3*SMA(RSV2,5,1)-2*SMA(SMA(RSV2,5,1),3,1),LINETHICK2,COLORFF84FF;
K:SMA(RSV2,3,1),LINETHICK2,COLORWHITE;
D:SMA(K,3,1),LINETHICK2,COLORF408F4;
{見頂信號:100,COLORCCFF00;}
買點準備:IF(趨勢線<=10,30,0),LINETHICK2,COLORYELLOW;
出點準備: IF(CROSS(J2,J1) AND J2>85,70,100),LINETHICK2,COLOR00FF00;
強弱界線:49,POINTDOT,LINETHICK3,COLOR99AACC;
{以下設置副圖顯示方式}
STICKLINE(趨勢線>88,100,趨勢線,4,1),COLORGREEN;
STICKLINE(趨勢線<=10,0,趨勢線,4,1),COLORYELLOW;
STICKLINE(COUNT(趨勢線<REF(趨勢線,1) AND 趨勢線<10,2)=2,0,20,4,0),COLORRED;
STICKLINE(CROSS(J2,J1) AND J2>85,100,80,4,0),COLORGREEN;
DRAWICON(CROSS(趨勢線,49),趨勢線,1),COLORRED;
DRAWICON(FILTER(CROSS(D,K) AND D>81,10),D*1.05,2);
DRAWTEXT(CROSS(趨勢線,49),47,'轉強'),COLORRED;
DRAWTEXT(CROSS(49,趨勢線),52,'轉弱'),COLORGREEN;

 

TDX
{估抄底F}

STICKLINE(C>0,0,100,15,0),COLOR7C221C;
RSV1:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
RSV2:=(CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100;
WEN:=3*SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1)-2*SMA(SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1),3,1);
J1:=SMA(RSV1,3,1);J2:=SMA(J1,3,1);
W1:=SMA(RSV2,3,1);W2:=SMA(W1,3,1);
強弱界線:49,POINTDOT,LINETHICK3,COLOR9966CC;
見頂信號:100,COLORCCFF00;

出點準備: IF(CROSS(J2,J1) AND J2>85,70,100),LINETHICK2,COLOR00FF00;
趨勢線: WEN,LINETHICK2;
買點準備:IF(趨勢線<=10,30,0),LINETHICK2,COLORYELLOW;
G1:w1,LINETHICK2,COLORWHITE;
G2:w2,LINETHICK2,COLORCYAN;
STICKLINE(趨勢線>88,100,趨勢線,3,1),COLORGREEN;
STICKLINE(趨勢線<=10,0,趨勢線,3,1),COLORYELLOW;
STICKLINE(COUNT(趨勢線<REF(趨勢線,1) AND 趨勢線<10,2)=2 ,0,20,3,0),COLORRED;
STICKLINE(CROSS(J2,J1) AND J2>85,100,80,3,0),COLORGREEN;
DRAWICON(CROSS(趨勢線,49),趨勢線,1);
DRAWICON(FILTER(CROSS(G2,G1) AND G2>81,10),G2*1.05,2);
DRAWTEXT(CROSS(趨勢線,49),47,'轉強'),COLORRED;
DRAWTEXT(CROSS(49,趨勢線),52,'轉弱'),COLORGREEN;

FOX
{估抄底F}

DRAWGBK(1,COLORRGB(20,50,50),COLORRGB(30,30,140),1);
RSV1:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
RSV2:=(CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100;
WEN:=3*SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1)-2*SMA(SMA((CLOSE-LLV
(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1),3,1);
J1:=SMA(RSV1,3,1);J2:=SMA(J1,3,1);
W1:=SMA(RSV2,3,1);W2:=SMA(W1,3,1);
強弱界線:49,POINTDOT,LINETHICK3,COLOR9966CC;
見頂信號:100,COLORCCFF00;

出點準備: IF(CROSS(J2,J1) AND J2>85,70,100),LINETHICK2,COLOR00FF00;
趨勢線: WEN,LINETHICK2,COLORFF84FF;
買點準備:IF(趨勢線<=10,30,0),LINETHICK2,COLORYELLOW;
G1:W1,LINETHICK2,COLORWHITE;
G2:W2,LINETHICK2,COLORCYAN;
STICKLINE(趨勢線>88,100,趨勢線,5,1),COLORGREEN;
STICKLINE(趨勢線<=10,0,趨勢線,5,1),COLORYELLOW;
STICKLINE(COUNT(趨勢線<REF(趨勢線,1) AND 趨勢線<10,2)=2 ,0,20,8,0),COLORRED;
STICKLINE(CROSS(J2,J1) AND J2>85,100,80,8,0),COLORGREEN;
DRAWICON(CROSS(趨勢線,49),趨勢線,4),COLORRED;
DRAWICON(FILTER(CROSS(G2,G1) AND G2>81,10),G2*1.05,2);
DRAWTEXT(CROSS(趨勢線,49),47,'轉強'),ALIGN0,COLORRED;
DRAWTEXT(CROSS(49,趨勢線),52,'轉弱'),ALIGN0,COLORGREEN;

 

DZH
{估抄底F}

RSV1:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
RSV2:=(CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100;
WEN:=3*SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1)-2*SMA(SMA((CLOSE-LLV (LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1),3,1);
J1:=SMA(RSV1,3,1);J2:=SMA(J1,3,1);
W1:=SMA(RSV2,3,1);W2:=SMA(W1,3,1);
強弱界線:49,POINTDOT,LINETHICK3,COLOR9966CC;
見頂信號:100,COLORCCFF00;

出點準備: IF(CROSS(J2,J1) AND J2>85,70,100),LINETHICK2,COLOR00FF00;
趨勢線: WEN,LINETHICK2,COLORFF84FF;
買點準備:IF(趨勢線<=10,30,0),LINETHICK2,COLORYELLOW;
G1:W1,LINETHICK2,COLORWHITE;
G2:W2,LINETHICK2,COLORCYAN;
STICKLINE(趨勢線>88,100,趨勢線,5,1),COLORGREEN;
STICKLINE(趨勢線<=10,0,趨勢線,5,1),COLORYELLOW;
STICKLINE(COUNT(趨勢線<REF(趨勢線,1) AND 趨勢線<10,2)=2 ,0,20,8,0),COLORRED;
STICKLINE(CROSS(J2,J1) AND J2>85,100,80,8,0),COLORGREEN;
DRAWICON(CROSS(趨勢線,49),趨勢線,7),COLORRED;
DRAWICON(FILTER(CROSS(G2,G1) AND G2>81,10),G2*1.05,2);
DRAWTEXT(CROSS(趨勢線,49),47,'轉強'),ALIGN0,COLORRED;
DRAWTEXT(CROSS(49,趨勢線),52,'轉弱'),ALIGN0,COLORGREEN;

 

青云直上主圖
精準買賣
DRAWGBKLAST(CLOSE>0,STRIP(RGB(95,95,95),RGB(0,0,0),0));
AA05:MA(C,5),color0099cc;
五日乖離率:=(c-AA05)/AA05*100;
BB05:=atan((aa05/ref(aa05,1)-1)*100)*180/3.1416;
速度5:=sma(ema((AA05-ref(AA05,1))/ref(AA05,1),3)*100,3,1);
加速度5:ema((速度5-ref(速度5,1)),3),linethick0;
STICKLINE(BB05>30 and AA05>ref(AA05,1), AA05,REF(AA05,1),8,1),colorcyan;
AA10:MA(C,10);AA20:=MA(c,20);
BB10:=atan((aa10/ref(aa10,1)-1)*100)*180/3.1416;
STICKLINE(BB05<0 and AA05<ref(AA05,1), AA05,REF(AA05,1),8,1),coloryellow;
AA30:MA(C,30);
三拾日乖離率:(c-AA30)/AA30*100,linethick0;
Var1:=(AA20-AA30)>ref((AA20-AA30),1) and AA20>ref(aa20,1) and AA30>ref(AA30,1);
Var2:=(AA30-AA20)<ref((AA30-AA20),1) and AA20<ref(aa20,1) and AA30<ref(AA30,1);
BB30:=atan((aa30/ref(aa30,1)-1)*100)*180/3.1416;
STICKLINE(BB30>15 and AA30>ref(AA30,1), AA30,REF(AA30,1),8,1),colorff00ff;
強勢狙擊:=filter(BB30>30 and BB10>45 and cross(BB05,60),10);
加倉:=filter(count(cross(BB05,30),5)>=1 and AA05>ref(aa05,1)  and 三拾日乖離率>ref(三拾日乖離率,1) and AA10>ref(AA10,1)
and 加速度5>ref(加速度5,1) and 速度5>ref(速度5,1)  ,10) ;
清倉:=filter(count(cross(30,BB05),5)>=1 and (c>AA30 or O>AA30) and AA05<ref(aa05,1)  and 三拾日乖離率<ref(三拾日乖離率,1) and AA10<ref(AA10,1),10);
drawtext(加倉 ,low*0.98,'←加倉'),colorred;
JC:=cross(0,五日乖離率) and 三拾日乖離率<ref(三拾日乖離率,1) and AA10>ref(AA10,1) ;
減倉:=filter(JC,10);
MR:=count(cross(五日乖離率,0),3)>=1 and 三拾日乖離率>ref(三拾日乖離率,1) and AA05>ref(AA05,1) and (c/ref(c,1)-1)*100>5 and ref(c,1)<AA30;
買入:=filter(MR,10);
drawtext(減倉,high*1.02,'←減倉'),colorcyan;
drawtext(買入,low*0.98,'←買入'),coloryellow;
drawtext(清倉 ,high*1.02,'←清倉'),colorgreen;
drawtext(強勢狙擊,LOW*0.98,'←強勢狙擊'),coloryellow;
Var21:=MAX(ABS(HIGH-AMOUNT/VOL/100),ABS(AMOUNT/VOL/100-LOW));
Var3:=ABS((OPEN+CLOSE)/2-AMOUNT/VOL/100);
MV:=(Var21+Var3)/AMOUNT*VOL*100*50;
DRAWTEXT(MV>6 and l<=llv(l,10),l*0.95,'←異動'),colorcyan;

 

青云直上選股器

青云直上指標發布后,受到朋友們的喜愛.在此我向大家表示深切的感謝!

有朋友希望我將指標中的"買入","加倉","強勢狙擊"寫成選股公式,現將公式寫在下面,希望朋友們能喜歡.

QYZS選股
AA05:=MA(C,5);
五日乖離率:=(c-AA05)/AA05*100;
BB05:=atan((aa05/ref(aa05,1)-1)*100)*180/3.1416;
速度5:=sma(ema((AA05-ref(AA05,1))/ref(AA05,1),3)*100,3,1);
加速度5:=ema((速度5-ref(速度5,1)),3);
AA10:=MA(C,10);AA20:=MA(c,20);
BB10:=atan((aa10/ref(aa10,1)-1)*100)*180/3.1416;
AA30:=MA(C,30);
三拾日乖離率:=(c-AA30)/AA30*100;
Var1:=(AA20-AA30)>ref((AA20-AA30),1) and AA20>ref(aa20,1) and AA30>ref(AA30,1);
Var2:=(AA30-AA20)<ref((AA30-AA20),1) and AA20<ref(aa20,1) and AA30<ref(AA30,1);
BB30:=atan((aa30/ref(aa30,1)-1)*100)*180/3.1416;
強勢狙擊:filter(BB30>30 and BB10>45 and cross(BB05,60),10);
加倉:filter(count(cross(BB05,30),5)>=1 and AA05>ref(aa05,1)  and 三拾日乖離率>ref(三拾日乖離率,1) and AA10>ref(AA10,1)
and 加速度5>ref(加速度5,1) and 速度5>ref(速度5,1)  ,10) ;
MR:=count(cross(五日乖離率,0),3)>=1 and 三拾日乖離率>ref(三拾日乖離率,1) and AA05>ref(AA05,1) and (c/ref(c,1)-1)*100>5 and ref(c,1)<AA30;
買入:filter(MR,10);

 

下面是選股思路如下:
1.分時走勢圖下的白線（股價）和黃線（均價)之間的振幅要能隨個人喜好控制.
2.白線（股價）和黃線（均價)粘合在一起時的時間長短要能隨個人喜好控制.
3.白線（股價）和黃線（均價)之間的上下關系最好是要能隨個人喜好控制.
4.個股當時的漲跌幅要能隨個人喜好調節.
5.DDX和DDY,DDZ正式用戶可以自己設定.
6.軟件自動監控預警(大多軟件都有此功能).
7.選出股票后再仔細觀察它的基本面和當時的量能.

除第5是DDE,我們是老百姓啊用免費就行,分時不需要它.第7中的看基本面,想要到其它地方拿來放進去就可以看了,這個也不放了.
其它條件基本完成.若做的不好請同學們指點,本人可是盡力了(水平有限沒辦法).
這個指標可繼續優化.可自已調節參數,做到你有多大本領你就調多少,自已炒股自作主.可預警可選股.也可做下跌提示等等..................

【分時橫盤】(優化版),

tt:=BARSCOUNT(C);
CC:=CLOSE;
zz:=SUM(AMOUNT,tt)/SUM(VOL*100,tt);
zz1:=BETWEEN(C/zz,1.05,0.95);
均線:IF(zz1=0,MA(C,TT),zz),COLOR00FFFF,LINETHICK2;
上均:均線 + AVEDEV(C,tt)*2,COLOR00FF00;
下均:均線 - AVEDEV(C,tt)*2,COLORFF6600;
時長:=if(HOUR>=13 AND HOUR<15 ,1,0);
漲幅:=(close/DYNAINFO(3))>=1.03;
跌幅:=(close/DYNAINFO(3))<=0.97;
漲跌幅:=漲幅 OR 跌幅;
yy:=SMA(vol,30,1);
放量:=(yy-LLV(Llv(yy,1),30))/(HHV(Hhv(yy,1),30)-LLV(Llv(yy,1),30))>0;
橫盤:=((HHV(CLOSE,TT)-LLV(CLOSE,TT))/CLOSE)<=0.05;
橫漲:=漲跌幅=0 and 橫盤 and 時長 and 放量  and CROSS(CC,上均)and DYNAINFO(22)<DYNAINFO(23) ;
橫跌:=漲跌幅=0 and 橫盤 and 時長 and 放量  and CROSS(下均,CC) ;
PP:= FILTER(橫漲,100) ;
UU:= FILTER(橫跌,50) ;
DRAWTEXT(PP,上均,'★上突'),colorff00ff;
DRAWTEXT(UU,下均,'★下破'),COLOR00FFFF;
VERTLINE( PP,3),COLORWHITE,LINETHICK2;
VERTLINE( UU,3),COLOR00FF00,LINETHICK2;

下面有二張分時圖參考,本指標其實是一個基本的框架指標.只是一間房子,里面你想怎么裝修你就怎么裝修.就是不斷加入你認為好的功能和條件.使其達到自已想達到的目的

 

橫盤后上漲分筆預警.
加外盤大于內盤

tt:=BARSCOUNT(C);
CC:=CLOSE;
zz:=SUM(AMOUNT,tt)/SUM(VOL*100,tt);
zz1:=BETWEEN(C/zz,1.05,0.95);
均線:=IF(zz1=0,MA(C,TT),zz);
上均:=均線 + AVEDEV(C,tt)*2;
下均:=均線 - AVEDEV(C,tt)*2;
時長:=if(HOUR>=13 AND HOUR<15 ,1,0);
漲幅:=(close/DYNAINFO(3))>=1.03;
跌幅:=(close/DYNAINFO(3))<=0.97;
漲跌幅:=漲幅 OR 跌幅;
yy:=SMA(vol,30,1);
放量:=(yy-LLV(Llv(yy,1),30))/(HHV(Hhv(yy,1),30)-LLV(Llv(yy,1),30))>0;
橫盤:=((HHV(CLOSE,TT)-LLV(CLOSE,TT))/CLOSE)<=0.05;
橫盤上漲:=漲跌幅=0 and 橫盤 and 時長 and 放量  and CROSS(CC,上均)and DYNAINFO(22)<DYNAINFO(23);
上突:FILTER(橫盤上漲,50);

橫盤后下跌分筆預警.

tt:=BARSCOUNT(C);
CC:=CLOSE;
zz:=SUM(AMOUNT,tt)/SUM(VOL*100,tt);
zz1:=BETWEEN(C/zz,1.05,0.95);
均線:=IF(zz1=0,MA(C,TT),zz);
上均:=均線 + AVEDEV(C,tt)*2;
下均:=均線 - AVEDEV(C,tt)*2;
時長:=if(HOUR>=13 AND HOUR<15 ,1,0);
漲幅:=(close/DYNAINFO(3))>=1.03;
跌幅:=(close/DYNAINFO(3))<=0.97;
漲跌幅:=漲幅 OR 跌幅;
yy:=SMA(vol,30,1);
放量:=(yy-LLV(Llv(yy,1),30))/(HHV(Hhv(yy,1),30)-LLV(Llv(yy,1),30))>0;
橫盤:=((HHV(CLOSE,TT)-LLV(CLOSE,TT))/CLOSE)<=0.05;
橫盤下跌:=漲跌幅=0 and 橫盤 and 時長 and 放量  and CROSS(下均,CC) ;
下破:FILTER(橫盤下跌,50) ;

 

 

 

通達信源碼：
{界文KD}
N1:=7;N2:=27;
STICKLINE(C>0,40,60,10,0),COLOR999999;
RSV:=(CLOSE-LLV(LOW,N1))/(HHV(HIGH,N1)-LLV(LOW,N1))*100;
短K:SMA(RSV,3,1),COLORF580F5,LINETHICK0;
短D:SMA(短K,3,1),COLORCCDD33,LINETHICK0;
RSV1:=(CLOSE-LLV(LOW,N2))/(HHV(HIGH,N2)-LLV(LOW,N2))*100;
中K:SMA(RSV1,5,1),COLORRED,LINETHICK0;
中D:SMA(中K,10,1),COLOR33AA33,LINETHICK0;
底線:10,COLORWHITE;
頂線:90,COLOR00FFFF;
STICKLINE(短K>短D,短K,短D,3,1),COLORF580F5;
STICKLINE(短K<=短D,短K,短D,3,1),COLORCCDD33;
STICKLINE(中K>中D,中K,中D,2,0),COLOR0000EF;
STICKLINE(中K<=中D,中K,中D,2,0),COLOR33AA33;