|
從2011-06-20以來的最近這段時間，上證指數大盤出現了幾次“百日地量”，但是有兩次出現在下跌中繼途中。
如果我們把“成交量”換成“成交金額”，則可以看出，成交額的“百日地量”更準確地出現在大盤的相對低點，為我們研判大盤的相對底部，提供更為實用的參考價值。
下面根據筆者在“股海明燈論壇”的個人空間日志發表的公式：通達信軟件(量柱)直觀顯示：倍量柱+三天價漲量縮=真黃金柱公式（帶低量柱）
http://u./space.php?uid=30578do=blogid=1201
將“成交量”換成“成交金額”，編成“成交額附圖公式”（適用于通達信行情軟件），供大家參考。這個也與《狙擊漲停板》作者張華老師的理念相符。
具體圖形請參閱：從成交額看今日大盤是百日地量（http://blog.sina.com.cn/s/blog_7f809c880100up3h.html）
{成交額附圖公式
VOL_日志改AM 用成交額代替成交量}
{看圖說明：黃色為倍量柱，白色為并肩平量柱，紫色為縮倍柱，
綠色為10天低量柱，藍色為50天低量柱，灰色為百日低量柱，
高量柱容易看無標記，！為長陰短柱, 內有紅實線為假陰柱。
紅色箭頭(的前三天)為黃金柱。次黃金柱難判,不標記}
綠低量:=10;{178448-WEN98編制}
藍低量:=50;
灰低量:=100;
{--------VOL.量能飽和--------}
N1:=21;
AM:= AMOUNT/100000000,NODRAW;{成交額億}
SAT:=(AM/C)/(HHV(AM,20)/HHV(C,20));
量能飽和度:IF(SAT>1,1,SAT)*100,COLOR00AAFF,NODRAW;
中點:=REFDATE(HHV(AM,180)*0.5,DATE);
STICKLINE(CURRBARSCOUNT=N1,中點*1.9,中點*1.5,100,1),COLOR00AAFF;
STICKLINE(CURRBARSCOUNT=N1,中點*1.88,中點*1.52,量能飽和度,0),COLOR0077FF;
DRAWTEXT(CURRBARSCOUNT=N1+3,中點*1.8,'飽和度'),COLORYELLOW;
{=====================================================}
H_L:=0.1*CONST(HHV(AM,240));
{MAV10:MA(V,10),COLORYELLOW;}
異動135:MA(AM,135),COLORMAGENTA;
洗盤40:MA(AM,40),COLORBLUE;
啟動5:MA(AM,5),COLORWHITE;
VVOL:=IF(CURRBARSCOUNT=1 AND
PERIOD=5,AM*240/FROMOPEN,DRAWNULL);{模擬量}
STICKLINE(CURRBARSCOUNT=1 AND
PERIOD=5,VVOL,0,1,-1),COLOR00C0C0;
量:V,COLORGREEN,NODRAW;
成交額億:AM,VOLSTICK,COLORLIGRAY;
換手: VOL*10000/FINANCE(7),NODRAW,COLORGREEN;
{DYNAINFO(37)*100}
全換手周期: SUMBARS(V,CAPITAL),NODRAW,COLORLIGREEN;{求完全換手到現在的周期數}
量比: V/REF(MA(V,5),1),COLORBROWN,NODRAW;
幾倍: AM/REF(AM,1),COLORYELLOW,NODRAW;
倍數:=1.9;{178448-WEN98編制}
倍量: AM>=REF(AM,1)*倍數 AND
(IF(C<O,C>REF(C,1),1)),COLORYELLOW,NODRAW;
倍縮: REF(AM,1)>=AM*倍數,COLORMAGENTA,NODRAW;
平量: RANGE(AM/REF(AM,1),0.97,1.03) AND
BARSCOUNT(V)>=2,COLORWHITE,NODRAW;
低量10: AM=LLV(AM,綠低量) AND
BARSCOUNT(AM)>=綠低量,COLORGREEN,NODRAW;
低量50: AM=LLV(AM,藍低量) AND
BARSCOUNT(AM)>=藍低量,COLORBLUE,NODRAW;
地量: AM=LLV(AM,灰低量) AND
BARSCOUNT(AM)>=灰低量,COLORGRAY,NODRAW;
V1:=AM*0.9;{圖標位置}
V2:=AM*0.8;
STICKLINE(倍量, 0,V1,1,0),COLORYELLOW;
STICKLINE(平量,0,V1,1,0),COLORWHITE;
STICKLINE(低量10,0,V2,1,0),COLORLIGREEN;
STICKLINE(低量50,0,V2,1,0),COLORBLUE;
STICKLINE(地量,0,V2,1,0),COLORGRAY;
STICKLINE(倍縮,0,AM*0.45,1,0),COLORMAGENTA;
STICKLINE(C<O AND
C>REF(C,1),0,AM,0,0),COLORRED;{假陰柱}
真陽或假陰:=C>O OR
C>REF(C,1);
收陽:= REF(真陽或假陰,3);
倍量1:=REF(倍量,3);
高量:=REF(AM,3)>=HHV(AM,7);
三日不破:= LLV(C,3)>=REF(L,3);
價升:=COUNT(C>=REF(C,1),3)=3;{收盤價逐升}
量縮:=COUNT(AM<=REF(AM,1),3)=3;
連陽:= COUNT(真陽或假陰,3)=3;
倍量將軍柱:= 倍量1 AND 三日不破 AND 收陽;
高量將軍柱:= 高量 AND 三日不破 AND 收陽;
將軍柱:= 倍量將軍柱 OR 高量將軍柱;
黃金柱:= 將軍柱 AND 價升 AND 量縮 AND 連陽 ;
STICKLINE(黃金柱,0.3*AM,0.7*AM,1,0),COLORRED; {紅柱}
DRAWICON(黃金柱,AM*1.5,1);
V100:= AM<=LLV(AM,100)*1.2
AND V>0 AND BARSCOUNT(AM)>=100;
百日地量群:=COUNT(V100,5)>=3;
DRAWTEXT(FILTER(百日地量群,4),AM+3*H_L,'地量群'),COLORGRAY;
長陰短柱:=C/REF(C,1)<=0.96 AND
AM<HHV(AM,30)/1.9;
DRAWTEXT(長陰短柱 ,AM+1.6*H_L,'！'),COLORLICYAN;
|
