通達(dá)信指標(biāo)公式編寫教程 第3節(jié)公式編寫示例

第3節(jié)公式編寫示例 

3.1 簡單公式
這里舉一些最簡單的公式例子，有些只有一條語句且函數(shù)簡單，較復(fù)雜的公式中函數(shù)復(fù)雜且語句較多。

收盤價線
這是最簡單的公式：
CLOSE;
均線
計算 N 日內(nèi)收盤價的算術(shù)平均值，它是最常用的指標(biāo)之一，公式為：
MA(CLOSE,５);
其中的 MA(X,N)表示 X 的 N 日平均。

漲幅
漲幅指今日收盤價相對于昨日收盤價的變動幅度，即（今日收盤價－昨日收盤價）／昨日收盤價*100%， 昨日收盤價的公式為：REF(CLOSE,1)，
因此漲幅的公式：
(CLOSE-REF(CLOSE,1))/REF(CLOSE,1);

換手率
換手率指當(dāng)期的成交量占流通股本的比例。
公式：
VOL/CAPITAL;
VOL 為當(dāng)期成交量，CAPITAL 為流通股本。

創(chuàng)新高
創(chuàng)新高指當(dāng)日最高價是最近一段時間的最高價：
HIGH=HHV(HIGH,N);
其中的 HIGH 為當(dāng)期最高價，HHV(X,N)是求 N 周期內(nèi) X 最高值。因此該公式的含義是當(dāng)日最高價創(chuàng)Ｎ日新高時返回值為１，否則為０。

橫盤整理
橫盤整理指最近一段時期價格在一定幅度之內(nèi)擺動：
(HHV(CLOSE,10)-LLV(CLOSE,10))/CLOSE<0.05;
其中的 LLV(X,N)是求 N 周期內(nèi) X 最低值。因此該公式表示 10 日收盤價振幅振幅在 5%以內(nèi)。

區(qū)間統(tǒng)計
例如，要取得 2002 年 2 月 1 日到 2002 年 12 月 30 日間的最低價。思考一下，一段時間的最低價必然是該段時間內(nèi)每個分析周期的最低價中最小的那個。所以我們要引用的數(shù)據(jù)是該段時間各分析周期的最低價，而不需要用到開盤價、收盤價或最高價；還要將不需要的數(shù)據(jù)，即區(qū)間外的數(shù)據(jù)設(shè)為０。
語句為：
LL:=IF(YEAR=2002 AND MONTH>=2 AND MONTH<=12,LOW,0);
該語句用一個條件函數(shù)來判斷時間是否處于規(guī)定區(qū)間，若是則返回最低價，否則返回０。
我們再用 LLV 函數(shù)，就可求得該段時間最低的最低價：
LLV(LL,N);
N 為日期參數(shù)，N 為 0，則上式表示：上市以來的最低價。

技術(shù)指標(biāo)公式
技術(shù)指標(biāo)公式用于繪制技術(shù)指標(biāo)線。以 KDJ 指標(biāo)為例，右鍵點(diǎn)擊 KDJ，選擇“編輯公式”后打開公式算法編輯器，顯示出 KDJ 指標(biāo)公式的內(nèi)容。
參數(shù)名稱: 最小值 最大值 缺省值
N: 1 10O 9
M1: 2 40 3
M2: 2 40 3
RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
K:SMA(RSV,M1,1)；
D:SMA(K,M2,1);
J:3*K-2*D
該公式繪制 K、D、J 兩條指標(biāo)線。
RSV 行是一個中間語句，計算當(dāng)期收盤價與 N 天內(nèi)最低價之差除以 N內(nèi)最高價與最低價之差的比值，再乘以系數(shù) 100。
K 線為 RSV 的 M1 天移動平均線；
D 線為線 K 的 M2 天移動平均線；
J 線為 K 線與 J 線的差值。

條件選股公式
條件選股用于選出滿足條件的股票，條件選股公式用于顯示條件是否滿足的語句是一個邏輯表達(dá)式，條件滿足，表達(dá)式的返回值為“1”，表示選中該股，條件不滿足，返回值為為“0”，表示未選中。條件選股公式的其他公式必須是中間公式，而且要在邏輯表達(dá)式之前。以 KDJ 指標(biāo)買入條件選股為例，右鍵點(diǎn)擊“KDJ 指標(biāo)買入條件選股”，選擇“編輯公式”后打開公式算法編輯器，顯示出公式的內(nèi)容。用 KDJ 隨機(jī)指標(biāo)作為買入條件是當(dāng) J 向上穿越 0 坐標(biāo)線的時候
公式寫法為：
參數(shù)名稱:最小值 最大值 缺省值
N: 1 10O 9
M1: 2 40 3
M2: 2 40 3
RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
K:SMA(RSV,M1,1);
D:SMA(K,M2,1);
J:3*K-2*D;
CROSS(J,0);
如果直接引用指標(biāo)公式，KDJ 條件選股公式可以簡寫為：
CROSS("KDJ.J"(N,M1,M2),0);

交易系統(tǒng)公式
交易系統(tǒng)公式用于描述交易系統(tǒng)。交易系統(tǒng)是一個完整的買賣過程。交易系統(tǒng)公式用來指示買入、賣出信號的語句是一個邏輯表達(dá)式，名

TERLONG:多頭買入
EXITLONG:多頭賣出
ENTERSHORT:空頭買入
EXITSHORT:空頭賣出
四種信號條件滿足，表達(dá)式的返回值為“1”，表示發(fā)出信號，條件不滿足，返回值為“0”，表示不發(fā)出信號。交易系統(tǒng)公式的其他公式必須是中間公式，而且要在邏輯表達(dá)式之前。
國內(nèi)的股市只用到 ENTERLONG，EXITLONG，國內(nèi)期貨市場還用到ENTERSHORT，EXITSHORT 語句。
當(dāng)買入或賣出條件滿足時，在什么時間、什么價位進(jìn)行操作，可以選擇本周期或次周期的開盤價、最高價、最低價、收盤價，在測試交易系統(tǒng)時將以設(shè)置的介入價格計算。若選擇次周期最高價買入、次周期最低價賣出，則此時的測試是最為嚴(yán)格，若此時交易系統(tǒng)的表現(xiàn)仍令人滿意，則說明該系統(tǒng)穩(wěn)定性好。
這里我們舉例說明如何編寫交易系統(tǒng)公式。以 KDJ 交易系統(tǒng)為例，右鍵點(diǎn)擊“KDJ 交易系統(tǒng)”，選擇“編輯公式”后打開公式算法編輯器，顯示
出公式的內(nèi)容。
交易系統(tǒng)的買入條件為 J 向上穿越 0；
賣出條件為 J 向下穿越 100。
參數(shù)名稱: 最小值 最大值 缺省值
N: 1 10O 9
M1: 2 40 3
M2: 2 40 3
RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
K:SMA(RSV,M1,1);
D:SMA(K,M2,1);
J:3*K-2*D;
ENTERLONG:CROSS(J,0);
EXITLONG:CROSS(100,J);
如果直接引用指標(biāo)公式，KDJ 交易系統(tǒng)公式可以簡寫為:
J:="KDJ.J"(N,M1,M2);
ENTERLONG:CROSS(J,0);
EXITLONG:CROSS(100,J);

K 線模式公式

K 線模式公式用于描述單根 K 線或多根 K 線組合的某種狀態(tài)。K 線模式公式用來指示模式的語句是一個邏輯表達(dá)式，最多可以設(shè)到 6 個，即 K 線圖上最多可以有 6 種彩色。以 KDJ 指標(biāo) K 線模式為例，在五彩 K 線項下的其他欄中找到“KDJ 隨機(jī)指標(biāo)”，用右鍵點(diǎn)擊，選擇“編輯公式”后打開公式編輯器，顯示出公式的內(nèi)容。
將 J 線值小于 0 的 K 線顯示為紅色，將 J 線值大于 100 的 K 線顯示為綠色。
參數(shù)名稱:最小值 最大值 缺省值
N: 1 10O 9
M1: 2 40 3
M2: 2 40 3
RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
K:=SMA(RSV,M1,1);
D:=SMA(K,M2,1);
J:=3*K-2*D;
J<0,COLORRED;
J>100,COLORGREEN;

曙光初現(xiàn)
是兩根 K 線的組合，其模式構(gòu)成為：
1、第一天的 K 線是陰線，表示市勢仍然向下；
2、隨后第二個交易日跳空低開；
3、其后時間出現(xiàn)強(qiáng)勁反彈，填補(bǔ)缺口后上升超過上日收盤價。此圖形如在底部出現(xiàn)，則稱為曙光初現(xiàn)，顯示市場可能見底回升。
根據(jù)此模式建立的公式為：
BACKSET( REF(CLOSE,1)/REF(OPEN,1)<0.97 AND CLOSE/OPEN>1.03
AND OPEN<REF(CLOSE,1) AND CLOSE>REF(CLOSE,1), 2)
BACKSET(X,N)是一個函數(shù)，若 X 非 0,則將當(dāng)前位置到 N 周期前的數(shù)值設(shè)為 1。
第一個參數(shù)中的第一個式子表示前一個周期的 K 線是陰線，
第二個式子表示當(dāng)前周期的 K 線是陽線，
第三個式子表示當(dāng)前周期是跳空低開，
第四個式子表示當(dāng)前周期填補(bǔ)低開缺口后收盤于上日收盤價之上。
第二個參數(shù)為 2，表示若第一個參數(shù)中設(shè)置的條件全部成立，則用不同的顏色把當(dāng)前周期和上一周期前的 K 線與其他 K 線區(qū)分開來。

3.2 指標(biāo)公式：均線通道

新建公式“均線通道”（JXTD）
1.使用快捷鍵 Ctrl+F 打開“公式管理器”。

2.點(diǎn)擊“新建”按鈕，打開“公式編輯器”

3.填寫公式項
“公式名稱”---JXTD,
“公式描述”---“均線通道”
參數(shù) （最小值）（最大值）（缺省值）
#N: 1 100 26
--------------------------------------------------
VAR1:=MA(CLOSE,N);{對“VAR1”賦值}
VAR2:=MA(CLOSE,2*N);{對“VAR2”賦值}
VAR3:=MA(CLOSE,3*N);{對“VAR3”賦值}
VAR4:=MA(CLOSE,4*N);{對“VAR4”賦值}
VAR5:=MA((VAR1+VAR2+VAR3+VAR4)/4,5);{一條多條均線的平均線}
上軌:VAR5*1.08;{在均線“VAR5”上加上 8%的幅度變成“上軌”}
下軌:VAR5*0.92; {在均線“VAR5”上減去 8%的幅度變成“下軌”}
----------------------------------------------------
4.指標(biāo)類型：選“路徑型”，還有大勢型、超買超賣型、趨勢型、能量型等如圖

5.畫線方法：副圖、主圖疊加、副圖疊加線、副圖疊加美國線四種；選中“主圖疊加型”，副圖是 K 線圖下面的區(qū)域；
6.密碼保護(hù)：010101
7.參數(shù)設(shè)置：#N：最小值為 1，最大值為 100，缺省值（默認(rèn)）為 26；
8.坐標(biāo)線位置：在非“主圖疊加”中，此編輯框處可寫狀態(tài)；輸出線為副圖中深紅色橫線顯示，是副圖坐標(biāo)線；
9.額外 Y 軸分界：是指標(biāo)敏感數(shù)值輸出線，在副圖中顯示為白色；
10.引入指標(biāo)公式：在引入原公式的基礎(chǔ)上進(jìn)行編輯；
11.插入函數(shù)：左上為函數(shù)類別，右上為函數(shù)表，下區(qū)為函數(shù)解釋區(qū)及用法舉例；

12.公式編輯區(qū)：
〖{ }〗是解釋，不輸出，為了提示自己和別人，便于看懂公式；
〖:=〗賦值符，意為“相當(dāng)于”；
〖:〗輸出符，它前面的名稱為輸出名稱，可以在副圖中看到，它后面的為公式定義；
〖；〗分段符，表示一段完成；
〖，〗分節(jié)符；
〖（）〗括號中為公式體。
13.測試公式：測試通過則自動保存；測試不能通過，則在翻譯區(qū)提示錯誤所在。
14.用法注釋：自編公式使用說明。
15.在 K 線圖上，直接敲字母鍵“JXTD”調(diào)出自編的公式“均線通道”，查看結(jié)果；
16.修改公式：左鍵選中公式線后，點(diǎn)擊右鍵，在彈出的對話框中，選中“修改指標(biāo)”項，直接調(diào)出《公式編輯器》修改公式。如果左鍵選指標(biāo)線不便，直接用右鍵選參數(shù)數(shù)值，也可調(diào)出公式編輯器。

17.鼠標(biāo)動態(tài)提示：將鼠標(biāo)放在函數(shù)上，等一會系統(tǒng)自動出現(xiàn)提示框，方便函數(shù)學(xué)習(xí)和應(yīng)用，如圖：

3.3 選股公式：均線通道

改公式“均線通道”（JXTD）為選股公式“均線通道”
1. 〖Ctrl〗+〖F〗打開“公式管理器”；
2. 點(diǎn)擊“條件選股公式”選項；
3. 點(diǎn)擊“新建”按鈕，打開“條件選股公式編輯器”；
4. 點(diǎn)擊“引入指標(biāo)公式”按鈕，選最后一項“均線通道”，確定；

5.修改輸出：公式輸出項改為賦值項；即將〖:〗符改為〖:=〗符；
6.新建輸出項：選股:CLOSE<下軌;{選出收盤價小于下軌的股票}；如

7.測試公式通過；
8. 〖Ctrl〗+〖T〗打開條件選股公式“均線通道”，進(jìn)入公式選股操作程序；

3.4 五彩 K 線公式：均線通道

改公式“均線通道”（JXTD）為五彩 K 線公式“均線通道”
1. 〖Ctrl〗+〖F〗打開“公式管理器”；
2. 點(diǎn)擊“五彩 K 線公式”選項；
3. 點(diǎn)擊“新建”按鈕，打開“K 線指示公式編輯器”；
4. 點(diǎn)擊“引入指標(biāo)公式”按鈕，選“均線通道”確定；

五彩 K 線公式
公式名：JXTD
公式描述：均線通道
參數(shù) （最小值）（最大值）（缺省值）
#N: 1 100 26
--------------------------------------------------
VAR1:=MA(CLOSE,N);{對“VAR1”賦值}
VAR2:=MA(CLOSE,2*N);{對“VAR2”賦值}
VAR3:=MA(CLOSE,3*N);{對“VAR3”賦值}
VAR4:=MA(CLOSE,4*N);{對“VAR4”賦值}
VAR5:=MA((VAR1+VAR2+VAR3+VAR4)/4,5);{一條多條均線的平均線}
上軌:=VAR5*1.08;{在均線“VAR5”上加上 8%的幅度變成“上軌”}
下軌:=VAR5*0.92; {在均線“VAR5”上減去 8%的幅度變成“下軌”}
CLOSE<下軌,COLORRED; {小于下軌提示買入紅色}
CLOSE>上軌,COLORYELLOW; {高于上軌提示賣出黃色}
HIGH>上軌*1.06,COLORBLUE;{高于上軌 6%提示清倉藍(lán)色}
LOW<下軌*0.94, COLORMAGENTA;{低于下軌 6%提示加倉洋紅色}
--------------------------------------------------
5.測試通過,退出；
6.〖Ctrl〗+〖K〗，打開“五彩 K 線指示”---“均線通道”；
7.查看效果，不滿意就修改參數(shù)一直到滿意為止；

3.5 交易系統(tǒng)公式

改公式“均線通道”（JXTD）為交易系統(tǒng)公式“均線通道”
1. 〖Ctrl〗+〖F〗打開“公式管理器”；
2. 點(diǎn)擊“交易系統(tǒng)公式”選項；
3. 點(diǎn)擊“新建”按鈕，打開“交易系統(tǒng)公式編輯器”；
4. 點(diǎn)擊“引入指標(biāo)公式”按鈕，選“均線通道”確定；
公式名：JXTD
公式描述：均線通道

參數(shù) （最小值）（最大值）（缺省值）
#N: 1 100 26
--------------------------------------------------
VAR1:=MA(CLOSE,N);{對“VAR1”賦值}
VAR2:=MA(CLOSE,2*N);{對“VAR2”賦值}
VAR3:=MA(CLOSE,3*N);{對“VAR3”賦值}
VAR4:=MA(CLOSE,4*N);{對“VAR4”賦值}
VAR5:=MA((VAR1+VAR2+VAR3+VAR4)/4,5);{一條多條均線的平均線}
上軌:=VAR5*1.08;{在均線“VAR5”上加上 8%的幅度變成“上軌”}
下軌:=VAR5*0.92; {在均線“VAR5”上減去 8%的幅度變成“下軌”}
{多頭買入} ENTERLONG:CLOSE<下軌;
{多頭賣出} EXITLONG:CLOSE>上軌;
---------------------------------------------------

5.測試通過,退出；
6.〖Ctrl〗+〖E〗，打開“五彩 K 線指示”---“均線通道”；
7.查看效果，不滿意就修改參數(shù)一直到滿意為止；

8.刪除指示：快捷鍵〖Ctrl〗+〖H〗；鼠標(biāo)左鍵選中指示圖標(biāo)，按〖Delete〗，或者點(diǎn)擊鼠標(biāo)右鍵，在彈出的菜單中選“刪除交易系統(tǒng)指示”。

3.6 顏色參數(shù)應(yīng)用：“MACD”K 線

公式名稱：MACDK
簡稱：“MACD”K 線
----------------------------
DIF:EMA(CLOSE,SHORT)-EMA(CLOSE,LONG);
DEA:EMA(DIF,MID);
MACD:(DIF-DEA)*2,COLORSTICK;
D1:=EMA(C,3)-EMA(C,8);
D2:=EMA(O,3)-EMA(O,8);
D3:=EMA(H,3)-EMA(H,8);
D4:=EMA(L,3)-EMA(L,8);
DRAWICON(CROSS(D1,DIF) AND DIF<0 ,D4-0.1,10);
DRAWICON(cross(diff,d1) and diff>0.1 ,d3+0.1,2);
STICKLINE(D1>=D2,D1,D2,8,0),COLOR0055AA;
STICKLINE(D1<=D2,D1,D2,8,0),COLOR006600;
STICKLINE(D1>=D2,D1,D2,5,0),COLOR0077CC;
STICKLINE(D1>=D2,D1,D2,3,0),COLOR0099DD;
STICKLINE(D1>=D2,D3,D4,0,0),COLOR00BBFF;
STICKLINE(D1<=D2,D1,D2,5,0),COLOR009900;
STICKLINE(D1<=D2,D1,D2,3,0),COLOR00BB00;

STICKLINE(D1<=D2,D3,D4,0,0),COLOR00EE00;
------------------------------

顏色參數(shù)不是函數(shù)，它描述待畫圖形的顏色，將其插入到每個指標(biāo)公式后面，用逗號分隔開。
常用顏色參數(shù)有：

COLORWHITE
顏色描述符還可以自定義顏色，格式為 COLOR+“RRGGBB”：RR、GG、BB 表示紅色、綠色和藍(lán)色的分量，每種顏色的取值范圍是 00-FF，采用了16 進(jìn)制。
例如：MA5：MA(CLOSE，5)，COLOR00FFFF 表示純紅色與純綠色的混合色：COLOR808000 表示淡藍(lán)色和淡綠色的混合色。

3.7 新增函數(shù)應(yīng)用 HORCALC(X)

公式名稱：ｚｄｋｘ
公式描述：自定指數(shù) K 線
參數(shù)：（最小值）（最大值）（缺省值）
#n: 1 100 10
---------------
高:=HORCALC('湖北板塊',100,0,1);
開:=HORCALC('湖北板塊',101,0,1);
低:=HORCALC('湖北板塊',102,0,1);
收:=HORCALC('湖北板塊',103,0,1);
自定 K 線: DRAWKLINE(高,開,低,收);
MA(自定 K 線,N);
---------------

公式說明：
１．用于制作自定義指數(shù)、自設(shè)板塊指數(shù) K 線。
２．先制作自定義板塊，“Ｃｔｒｌ＋ｚ”，填寫好板塊名稱和簡稱（數(shù)字）；
３．“板塊名稱”須用單引號，如'自選股'、'莊股'；
４．起始位為１０００點(diǎn)（下載到本地數(shù)據(jù)）；
５．板塊內(nèi)不要含有太多的股票數(shù)量，以免影響速度；

3.8 新增函數(shù)應(yīng)用 BLOCKSETNUM(板塊名稱)

公式名稱：STPM
公式描述：個股在 st 板塊內(nèi)排名
--------------
板塊股數(shù)量:BLOCKSETNUM('ST 板塊'),NODRAW;
ST 漲幅排名:HORCALC('ST 板塊',105,1,2);

說明：
NODRAW 是不輸出線型只輸出數(shù)值命令，用于多指標(biāo)不兼容坐標(biāo)；